Slik bruker du Caps Lock som en modifikasjonstast på Windows

Caps Lock-tasten tar opp prime keyboard eiendom, og den trekker ikke vekten. Dette enkle AutoHotkey-skriptet vil gjøre Caps Lock om til en modifikasjonstast slik at du kan bruke den til tilpassbare snarveier.

Det grunnleggende

Dette skriptet lar deg trykke på Caps Lock+G for raskt å Google tekst fra hvor som helst i Windows, eller trykk på Caps Lock+D for å slå opp ordbokdefinisjonen av et ord. Disse snarveiene kan selvfølgelig tilpasses.

Best av alt, dette smarte skriptet lar deg fortsatt bruke Caps Lock på vanlig måte. Du kan slå Caps Lock på og av ved å trykke raskt to ganger. Hvis du ikke gjør det, vil Caps Lock fungere som en modifikasjonstast for snarveier.

Autohurtigtast 101

AutoHotkey er et gratis Windows-program som sitter i bakgrunnen og kjører skript. Du kan skrive disse skriptene selv eller laste dem ned. Skript venter vanligvis på et tastetrykk og utfører en handling. På denne måten er AutoHotkey en rask måte å tilordne nøkler på nytt i Windows eller tilordne forskjellige handlinger til nøkler.

For eksempel har vi vist hvordan du kan bruke AutoHotkey til å deaktivere Windows-tasten, forhindre at den åpner Start-menyen og tar deg ut av fullskjerms PC-spill. Du trenger ikke å lirke tastaturet av tastaturet.

Installer AutoHotkey og få skriptet

Last ned AutoHotkey og installer den for å begynne. Deretter laster du ned CapsLock Modifier-skriptet.

Pakk ut AHK-skriptfilen fra ZIP-arkivfilen og plasser den i en hvilken som helst mappe på datamaskinen din. For å kjøre det med AutoHotkey, høyreklikk på skriptet og velg «Kjør skript.»

Skriptet kjører nå i bakgrunnen. For å slå Caps Lock på og av, dobbelttrykk raskt på Caps Lock-tasten.

Hvis du ikke dobbelttrykker, fungerer Caps Lock bare som en modifikasjonstast. Med funksjonene innebygd i skriptet kan du bruke følgende snarveier hvor som helst i Windows:

Trykk på Caps Lock + d for å finne ordbokdefinisjonen til et valgt ord.
Trykk på Caps Lock + g for å søke på Google etter den valgte teksten hvor som helst i Windows.
Trykk på Caps Lock + t for å finne det valgte ordet i en synonymordbok.
Trykk på Caps Lock + w for å søke etter den valgte teksten på Wikipedia.

Vil du ha flere snarveier? Du kan lage din egen med litt kunnskap om AutoHotkey-skript.

For å kontrollere AutoHotkey, se etter AutoHotkey-ikonet i varslingsområdet ditt – det har en grønn bakgrunn med en hvit H på. For å slutte å kjøre skriptet, høyreklikk på AutoHotkey-ikonet og velg «Avslutt».

Hvordan virker det?

Hvis du vil se hva skriptet gjør, høyreklikker du på det og velger «Rediger skript» i stedet. Dette vil åpne skriptet i Notisblokk, og du kan undersøke koden. Manuset er ganske kort og lett å forstå. Vi anbefaler at du ikke laster ned og kjører merkelige skript uten å se på dem og forstå dem først.

Dette manuset ble sendt til oss av Dave Kellog. Her er den magiske delen av skriptet som får Caps Lock til å fungere som en modifikasjonstast hvis den trykkes to ganger:

CapsLock::
KeyWait, CapsLock ; Wait forever until Capslock is released.
KeyWait, CapsLock, D T0.2 ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") ) ; Is a double tap on CapsLock?
{
SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On" ; Toggle the state of CapsLock LED
}
return

Denne biten venter for å se om Caps Lock trykkes to ganger og slår Caps Lock på eller av. Ellers fanger skriptet Caps Lock og bruker det til modifikator-snarveier.

Resten av skriptet inneholder snarveishandlingene og en nyttig utklippstavlefunksjon som lagrer innholdet på utklippstavlen og gjenoppretter dem. Den delen er ganske nødvendig, siden modifikasjonsfunksjonene bruker utklippstavlen til å utføre handlinger på den valgte teksten.

Vil du se hele skriptet uten å laste det ned? Her er det:

#NoEnv                      ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn                     ; Enable warnings to assist with detecting common errors.
#SingleInstance FORCE       ; Skip invocation dialog box and silently replace previously executing instance of this script.
SendMode Input              ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.


;================================================================================================
;  CapsLock processing.  Must double tap CapsLock to toggle CapsLock mode on or off.
;================================================================================================
; Must double tap CapsLock to toggle CapsLock mode on or off.
CapsLock::
    KeyWait, CapsLock                                                   ; Wait forever until Capslock is released.
    KeyWait, CapsLock, D T0.2                                           ; ErrorLevel = 1 if CapsLock not down within 0.2 seconds.
    if ((ErrorLevel = 0) && (A_PriorKey = "CapsLock") )                 ; Is a double tap on CapsLock?
        {
        SetCapsLockState, % GetKeyState("CapsLock","T") ? "Off" : "On"  ; Toggle the state of CapsLock LED
        }
return



;================================================================================================
; Hot keys with CapsLock modifier.  See https://autohotkey.com/docs/Hotkeys.htm#combo
;================================================================================================
; Get DEFINITION of selected word.    
CapsLock & d::
    ClipboardGet()
    Run, http://www.google.com/search?q=define+%clipboard%     ; Launch with contents of clipboard
    ClipboardRestore()
Return

; GOOGLE the selected text.
CapsLock & g::
    ClipboardGet()
    Run, http://www.google.com/search?q=%clipboard%             ; Launch with contents of clipboard
    ClipboardRestore()
Return

; Do THESAURUS of selected word
CapsLock & t::
    ClipboardGet()
    Run http://www.thesaurus.com/browse/%Clipboard%             ; Launch with contents of clipboard
    ClipboardRestore()
Return

; Do WIKIPEDIA of selected word
CapsLock & w::
    ClipboardGet()
    Run, https://en.wikipedia.org/wiki/%clipboard%              ; Launch with contents of clipboard
    ClipboardRestore()
Return

;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++

;================================================================================================
; Clipboard helper functions.
;================================================================================================
ClipboardGet()
{
    OldClipboard:= ClipboardAll                         ;Save existing clipboard.
    Clipboard:= ""
    Send, ^c                                            ;Copy selected test to clipboard
    ClipWait 0
    If ErrorLevel
        {
        MsgBox, No Text Selected!
        Return
        }
}


ClipboardRestore()
{
    Clipboard:= OldClipboard
}

Vi har sett AutoHotkey-skript som gjør Caps Lock til en modifikasjonstast før, men aldri en som holder Caps Lock rundt som en bryter hvis du dobbelttrykker den. Det er veldig smart. Takk igjen til Dave Kellog for at du sendte den til oss.